home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 008 / 68kgraph.arc / CREEP.ASM < prev    next >
Encoding:
Assembly Source File  |  1986-12-13  |  3.4 KB  |  97 lines
  1. ******************************************************************
  2. * COPYRIGHT (C) 1986 by Donald Krantz and James Stanley
  3. * - Note: This is a real, live, actual, registered copyright,
  4. *   and should be treated as such. This source code is from
  5. *   the book "68000 Assembly Language", Krantz and Stanley,
  6. *   Addison-Wesley Publishing Company, Reading, MA, 1986.
  7. * 
  8. *   Permission granted by the authors for non-commercial use
  9. *   in programs released to the public domain, as long as this
  10. *   copyright notice remains attached and visible.
  11. *
  12. *****************************************************************
  13. * CREEP - Does a "spreading dot" trick
  14. #bit.h
  15.  
  16.     xdef    creep
  17.     xref    g_pix,image
  18.  
  19. *****************************************************************
  20. * CREEP - Fills all "white" space adjacent to pixel (D0.W,D1.W)
  21. creep:
  22.     movem.w    d0-d4,-(a7)
  23.     move.w    d0,d2        * save pixel X
  24.     move.w    d1,d3        * save pixel Y
  25. lp1_cp:
  26.     bsr    tstpix        * check this pixel
  27.     bne    sk1_cp        * we're done if this one set
  28.     bsr    g_pix        * set this pixel
  29.     subq.w    #1,d0        * move left one pixel
  30.     bra    lp1_cp        * do it 'til we boink
  31. sk1_cp:
  32.     addq.w    #1,d0        * adjust right end X position
  33.     exg    d0,d2        * save leftmost, get original
  34.     addq.w    #1,d0        * move left of original
  35. lp2_cp:
  36.     bsr    tstpix        * check this pixel
  37.     bne    sk2_cp        * we're done if this one set
  38.     bsr    g_pix        * set this pixel
  39.     addq.w    #1,d0        * move right one pixel
  40.     bra    lp2_cp        * keep on to the right end
  41. sk2_cp:
  42.     subq.w    #1,d0        * adjust left end X position
  43.     move.w    d0,d4        * save left end X position
  44.  
  45.     move.w    d2,d0        * get left end X position
  46.     addq.w    #1,d1        * move down to next row
  47.     bsr    run        * check the run for adjacent pixs
  48.  
  49.     move.w    d2,d0        * get right end X limit
  50.     move.w    d3,d1        * get original Y
  51.     subq.w    #1,d1        * move up one row
  52.     bsr    run        * check for adjacent white pixels
  53.  
  54.     movem.w    (a7)+,d0-d4
  55.     rts
  56. *****************************************************************
  57. run:
  58.     bsr    tstpix        * check this pixel
  59.     bne    sk4_cp        * set, no need to worry
  60.     bsr    creep        * set the new line
  61. sk4_cp:
  62.     addq.w    #1,d0        * move right one pixel
  63.     cmp.w    d0,d4        * test against right limit
  64.     bge    run        * loop if more to check
  65.     rts
  66. *****************************************************************
  67. * TSTPIX - tests the pixel where D0.W = X and D1.W = Y
  68. *          returns zero flag TRUE if pixel not set
  69. tstpix:
  70.     movem.l    d0/d1/a0,-(a7)    * save caller's registers
  71. ******* See if X and Y are valid addresses *********************
  72.     tst.w    d0        * look for off left edge
  73.     bmi    sk1_pix        * error out if so
  74.     tst.w    d1        * look for off top
  75.     bmi    sk1_pix        * error out if so
  76.     cmp.w    #hor_b,d0    * look for off right edge
  77.     bge    sk1_pix        * error out if so
  78.     cmp.w    #vert,d1    * look for off bottom
  79.     bge    sk1_pix     * error out if so
  80. ******* pixel (X,Y) is valid; check value of pixel **************
  81.     move.l    #image,a0    * get base of image area
  82.     mulu    #(hor_w*2),d1    * get vertical offset to line
  83.     add.l    d1,a0        * and add to base address
  84.     move.w    d0,d1        * save X for later
  85.     lsr.w    #3,d0        * get number of bytes to pixel 
  86.     add.w    d0,a0        * add to pointer
  87.     and.w    #$0007,d1    * strip all but bit number
  88.     btst    d1,(a0)        * test the bit
  89.     bra    sk2_pix        * and exit
  90. sk1_pix:
  91.     andi    #$FB,ccr    * errors always show set pixel
  92. sk2_pix:
  93.     movem.l    (a7)+,d0/d1/a0    * restore caller's registers
  94.     rts
  95. *****************************************************************
  96.     end
  97.